;  This example code illustrates how to access and visualize ICESat-2
; ATL08 L3A version 4 HDF5 file in IDL. 
;
; If you have any questions, suggestions, comments  on this example, 
; please use the HDF-EOS Forum (http://hdfeos.org/forums).
;
; If you would like to see an  example of any other NASA HDF/HDF-EOS 
; data product that is not listed in the HDF-EOS Comprehensive Examples page
; (http://hdfeos.org/zoo), feel free to contact us at eoshelp@hdfgroup.org
; or post it at the HDF-EOS Forum (http://hdfeos.org/forums).

; Usage:
;
;  $idl ATL08_20210114234518_03361001_004_01.h5.idl
;
; Tested under: IDL 8.7.2
; Last updated: 2021-05-04

; Open file.
file_name='ATL08_20210114234518_03361001_004_01.h5'
file_id=H5F_OPEN(file_name)

; Read latitude.
latitude_name='/gt1l/land_segments/latitude'
latitude_id=H5D_OPEN(file_id, latitude_name)
lat=H5D_READ(latitude_id)

; Close dataset.
H5D_CLOSE, latitude_id

; Read longitude.
lon_name='/gt1l/land_segments/longitude'
lon_id=H5D_OPEN(file_id, lon_name)
lon=H5D_READ(lon_id)

; Close dataset.
H5D_CLOSE, lon_id


; Read data.
data_name='/gt1l/land_segments/dem_h'
data_id=H5D_OPEN(file_id, data_name)
data=H5D_READ(data_id)

; Read unit attribute.
units_id=H5A_OPEN_NAME(data_id, 'units')
units=H5A_READ(units_id)
H5A_CLOSE, units_id

; Read long name attribute.
ln_id=H5A_OPEN_NAME(data_id, 'long_name')
long_name=H5A_READ(ln_id)
H5A_CLOSE, ln_id

; Get fill value.
fillvalue_id=H5A_OPEN_NAME(data_id,'_FillValue')
fillvalue=H5A_READ(fillvalue_id)
H5A_CLOSE, fillvalue_id

; Close dataset.
H5D_CLOSE, data_id


; Close file.
H5F_CLOSE, file_id

; Process fill value.
idx=where(data eq fillvalue(0), cnt)
if cnt gt 0 then data[idx] = !Values.F_NAN

; Generate the plot.
; Retrieve dimension size of data.
dimsize=SIZE(lat,/dim)
numlat=dimsize(0)

; Set center point of map.
c_lon = lon[numlat/2]
c_lat = lat[numlat/2]

m = MAP('Orthographic', TITLE=file_name, FONT_SIZE=9, /BUFFER, $
        DIMENSIONS=[800,600], $
        CENTER_LONGITUDE = c_lon,  CENTER_LATITUDE = c_lat)
ct = COLORTABLE(72, /reverse)
t1 = TEXT(0.35, 0.9, long_name)
datamin=MIN(data, /NAN)
datamax=MAX(data, /NAN)
c1 = SCATTERPLOT(lon, lat, OVERPLOT=m, $
                 MAGNITUDE = data, $
                 RGB_TABLE=ct, $
                 POSITION=[0.1, 0.1, 0.83, 0.9],$
                 /SYM_FILLED, SYMBOL='o', SYM_SIZE=0.1)
mc = MAPCONTINENTS()

; We need custom colorbar because we use SCATTERPLOT().
; We cannot use TARGET=c1.
cb = COLORBAR(RGB_TABLE=ct, RANGE=[datamin, datamax], /BORDER, ORIENTATION=1, TEXTPOS=1, POSITION=[0.85,0.2,0.87,0.8], TITLE=units)
png = file_name + '.idl.png'
c1.save, png, HEIGHT=600, WIDTH=800
EXIT