;
;   This example code illustrates how to access and visualize GESDISC MERRA-2
; L3 HDF5 file in NCL. 
;
;  If you have any questions, suggestions, comments on this example, please 
; use the HDF-EOS Forum (http://hdfeos.org/forums). 
;
;  If you would like to see an  example of any other NASA HDF/HDF-EOS data 
; product that is not listed in the HDF-EOS Comprehensive Examples page 
; (http://hdfeos.org/zoo), feel free to contact us at eoshelp@hdfgroup.org or 
; post it at the HDF-EOS Forum (http://hdfeos.org/forums).

; Usage:save this script and run 
; 
; $ncl MERRA2_400.tavg3_3d_nav_Ne.20151226.nc4.ncl
; Tested under: NCL 6.3.0
; Last updated: 2016-02-01

 
load "$NCARG_ROOT/lib/ncarg/nclex/gsun/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"

; This is the main program.
begin
  file_name = "MERRA2_400.tavg3_3d_nav_Ne.20151226.nc4"


; Read file as an HDF5 file. 
  h5_file = addfile(file_name, "r") 
;  print(h5_file)
  g = h5_file=>/
  data = g->ZLE(0,0,:,:)
  lat = g->lat
  lon = g->lon
  lev = g->lev
  time = g->time
  data&lat = lat
  data&lon= lon
  data@long_name = data@long_name + " at " + time@long_name + " = " + time(0) + " " + time@units + " and " + lev@long_name + " = " + lev(0) + " " + lev@units
  wks = gsn_open_wks("png", file_name+".ncl") ; open workstation
  res=True
  res@gsnMaximize=True   ;make plot large
  res@gsnPaperOrientation = "portrait"    ;force portrait orientation
  res@gsnSpreadColors=True    ; use the entire color spectrum
  res@cnFillOn=True   ;enable contour fill
  res@cnLinesOn=False   ;turn off contour line
  res@cnLineLabelsOn =  False    ;turn off contour line labels
  res@cnFillMode="RasterFill"   ;faster
  res@lbLabelAutoStride= True
  res@lbOrientation="vertical" ;vertical labels
  res@trGridType = "TriangularMesh" 
  res@tiMainString = file_name
  res@gsnLeftStringFontHeightF = 12 ; make font smaller 
  res@gsnRightStringFontHeightF = 12 ; make font smaller   
  plot=gsn_csm_contour_map(wks,data,res)

  delete(plot)
  delete(data)
  delete(res)  
  delete(h5_file)
end